Módulo
Conteúdo
Índice 🔎︎

## Função CONT.SES

Retorna a contagem de células que conferem critérios em vários intervalos.

### Sintaxe

CONT.SES(Intervalo1; Criterio1 [; Intervalo2; Criterio2 [; ...]])

Intervalo – argumento obrigatório. Um intervalo, um nome de intervalo ou um rótulo de coluna ou linha contendo os números a contar e a achar o critério correspondente.

Critério1 – obrigatório. Uma expressão de texto representando uma condição lógica ou referência a uma célula contendo uma expressão de texto. A expressão pode conter texto, números, expressões regulares ou caracteres coringa (se estas estiverem ativadas nas opções de cálculo).

Intervalo2 – Opcional. Intervalo2 e os seguintes tem mesmo significado que Intervalo1

Critério2 – Opcional. Critério2 e todos os seguintes tem mesmo significado que Critério1.

Intervalo1, Intervalo2, ... e Critério1, Critério2, ... devem ter mesmo tamanho, senão a função retorna err:502 - Argumento inválido.

A relação lógica entre os critérios pode ser definida como E lógico (conjunção). Em outras palavras, se e somente se todos os critérios são verificados, um valor da célula correspondente do intervalo Intervalo_Func é computada.

A função pode ter até 255 argumentos, significando que pode haver 127 intervalos de critérios e critérios correspondentes.

Se uma célula contém VERDADEIRO, é tratada como 1, se tiver FALSO, é tratada como zero.

Esta função é parte integrante da norma Open Document Format for Office Applications (OpenDocument), versão 1.2 (ISO/IEC 26300:2-2015).

### Exemplo

#### Considere a seguinte tabela

| A | B | C
1 | Nome do produto | Vendas | Renda
2 | canudo | 20 | 65
3 | caneta | 35 | 85
4 | caderno | 20 | 190
5 | mochila | 17 | 180
6 | caneta tinteiro | nao | não

Em todos os cálculos abaixo, o intervalo para a soma contém a linha nº 6, que é ignorada por que contém um texto.

#### Utilização simples

=CONT.SES(B2:B6;">=20")

Conta o número de linhas no intervalo B2:B6 com valores maiores ou iguais a 20. Retorna 3 por que a 5ª e 6ª linhas não atendem ao critério.

=CONT.SES(B2:B6;">=20";C2:C6;">70")

Conta o número de linhas que contém simultaneamente valores maiores de 70 no intervalo C2:C6 e valores maiores que 20 no intervalo B2:B6. Retorna 2 por que a segunda e a 6ª linhas não conferem pelo menos uma das condições.

#### Usar expressões regulares e funções incorporadas

=CONT.SES(B2:B6;"[:alpha:]*")

Conta o número de linhas do intervalo B2:B6 que contém somente símbolos do alfabeto. Retorna 1 por que somente a 6ª linha atende ao critério.

=CONT.SES(B2:B6;">"&MÍNIMO(B2:B6);B2:B6;"<"&MÁXIMO(B2:B6))

Conta o número de linhas no intervalo B2:B6 excluindo as linhas de máximo e mínimo. Retorna 2 por que a 3ª, 5ª e 6ª linhas não atendem pelo menos um dos critérios.

=CONT.SES(A2:A6;"can.*";B2:B6;"<"&MÁXIMO(B2:B6))

Conta número de linhas que correspondem a todas as células do intervalo A2:A6 que começam com as letras "can" e todas as células do intervalo B2:B6 exceto seu máximo. Retorna 1 por que somente a segunda linha atende a todos os critérios.

#### Critério como referência

Se precisar mudar o critério mais facilmente, você pode especificar uma célula em separado e usar sua referência na condição para a função CONT.SES. Por exemplo, a função acima pode ser reescrita como:

=CONT.SES(A2:A6;E2&".*";B2:B6;"<"&MÁXIMO(B2:B6))

Se E2="can", a função retorna 1.

Tópicos relacionados

CONT.NÚM, CONT.SE, CONTAR.VAZIO, CONT.VALORES

Função CONT.SES, Função MÍNIMOSES, função MÁXIMOSES, Função MÉDIASES, Função SOMASES

Lista de expressões regulares