Módulo
Conteúdo
Índice 🔎︎

## Função MÉDIASE

Returna a média aritmética de todas as células no intervalo que satisfaçam uma condição apresentada. A função MÉDIASE soma todos os resultados que conferem a condição e divide pela quantidade dos valores selecionados.

### Sintaxe

MÉDIASE(Intervalo; Critério [; Intervalo_media ])

Intervalo – argumento obrigatório. Uma matriz, um nome de intervalo ou um rótulo de coluna ou linha contendo os números a calcular ou texto da condição.

critério – obrigatório. Uma condição na forma de expressão ou referência de célula que define quais células devem ser usadas para calcular a média. A expressão pode conter texto, números, expressões regulares (se ativadas nas opções do Calc) ou caracteres curinga (se ativado nas opções do Calc).

Intervalo_media – opcional. O intervalo de valores para calcular a média.

Note que se Intervalo_media não for especificado, o Intervalo será usado para ambos, o cálculo da média e o critério de pesquisa. Se Intervalo_media for especificado, o Intervalo será usado somente para a condição, enquanto Intervalo_media é suado para o cálculo da média.
O Criterio necessita ser uma expressão textual, em particular, o Criterio precisa estar entre aspas ("Criterio") com a exceção de nomes de função, referência de células ou uma operação de concatenação de cadeias de caracteres (&).

Esta função é parte integrante da norma Open Document Format for Office Applications (OpenDocument), versão 1.2 (ISO/IEC 26300:2-2015).

Se uma célula num intervalo de valores for zero ou um texto, a função MÉDIASE ignora esta célula.
Se o intervalo inteiro for vazio, contiver só textos ou se nenhum valor verificar a condição (ou qualquer combinação destes), a função retorna o erro #DIV/0!.

### Exemplo

#### Considere a seguinte tabela

| A | B | C
1 | Nome do produto | Vendas | Renda
2 | canudo | 20 | 65
3 | caneta | 35 | 85
4 | caderno | 20 | 190
5 | mochila | 17 | 180
6 | caneta tinteiro | nao | não

Em todos os cálculos abaixo, o intervalo para a soma contém a linha nº 6, que é ignorada por que contém um texto.

Em todos os cálculos abaixo, o intervalo para a média contém a linha nº 6, mas será ignorada por que contém um texto.

#### Usos simples

=MÉDIASE(B2:B6;"<35")

Calcula a média para os valores do intervalo B2:B6 que são menores de 35. Retorna 19 por que a segunda linha não participa do cálculo.

=MÉDIASE(B2:B6;"<"&MÁXIMO(B2:B6))

Calcula a média para valores do mesmo intervalo que são menores que o máximo valor do intervalo. Retorna 19 por que o maior valor (a segunda linha) não participa no cálculo.

=MÉDIASE(B2:B6;">"&MENOR(B2:B6;1))

Calcula a média para valores do mesmo intervalo que são maiores que o menor valor do intervalo. Retorna 25 por que o menor valor do intervalo (a 4ª linha) não participa do cálculo.

#### Utilizar o Intervalo_medio

=MÉDIASE(B2:B6;"<35";C2:C6)

A função pesquisa que valores são menores de 35 no intervalo B2:B6, e calcula a média correspondente dos valores do intervalo C2:C6. Retorna 145, por que a segunda linha não participa da conta.

=MÉDIASE(B2:B6;">"&MINIMO(B2:B6);C2:C6)

A função pesquisa que valores no intervalo B2:B6 são maiores que o menor valor no intervalo B2:B6, e calcula a média correspondente no intervalo C2:C6. Retorna 113,3, por que a 4ª linha (onde está o menor valor no intervalo B2:B6) não participa do cálculo.

=MÉDIASE(B2:B6;"<"&MAIOR(B2:B6;2);C2:C6)

A função pesquisa que valores do intervalo B2:B6 são menores que o segundo maior valor no intervalo B2:B6, e calcula a média correspondente no intervalo C2:C6. Retorna 180, por que só a 4ª linha participa da conta.

#### Usar expressões regulares

=MÉDIASE(A2:A6;"caneta";B2:B6)

A função pesquisa que células no intervalo A2:A6 contém a palavra "caneta", e calcula a média correspondente dos valores do intervalo B2:B6. Retorna 35 por que só a segunda linha participa da conta. A pesquisa é feita no intervalo A2:A3, mas o valor é retornado do intervalo B2:B6

=MÉDIASE(A2:A6;"can.*";B2:B6)

A função pesquisa que células do intervalo A2:A6 começam com "can", e terminam com qualquer número de caracteres para calcular a média dos valores correspondentes no intervalo B2:B6. Retorna 27,5, por que "canudo" também satisfaz a condição e as duas primeiras linhas participam da conta.

=MÉDIASE(A2:A6;".*book.*";B2:B6)

A função pesquisa que células no intervalo A2:A3 contém o texto "book" começando e terminando com outros caracteres e calcula a média correspondente no intervalo B2:B6. Retorna 18,5 por que somente a 3ª e 4ª linhas participam da conta.

#### Critério como referência

Se desejar mudar o critério mais facilmente, pode especificar uma célula separada e usá-la em referencia como condição para a função MÉDIASE.

=MÉDIASE(A2:A6;".*"&E2&".*";B2:B6)

A função pesquisa que células no intervalo A2:A6 contém uma combinação de caracteres especificada na célula E2 no meio de qualquer outras combinações de caracteres e calcula a média dos valores correspondentes no intervalo B2:B6. Se E2="book" então a função retorna 18,5.

=MÉDIASE(B2:B6;"<"&E2;C2:C6)

A função pesquisa que células do intervalo B2:B6 são menores que o valor especificado em E2 e calcula a média dos valores correspondentes do intervalo C2:C6. Se E2=35, a função retorna 145.

Tópicos relacionados

MÉDIA, MÉDIAA, DESV.MÉDIO

Função CONT.SES, Função MÍNIMOSES, função MÁXIMOSES, Função MÉDIASES, Função SOMASES

Lista de expressões regulares