Module
Contents
Index 🔎︎

# Tabelarvutuse funktsioonid

See sektsioon sisaldab tabelarvutuse funktsioonide kirjeldusi koos näidetega.

Selle käsu kasutamiseks...

Lisamine - Funktsioon - Kategooria Arvutustabel

## [text/scalc/01/func_error_type.xhp#error_type_head not found].

Returns a number representing a specific Error type, or the error value #N/A, if there is no error.

## ADDRESS

Tagastab lahtri aadressi (viite) teksti kujul vastavalt ette antud rea ja veeru numbritele. Võimalik on määrata, kas aadress on absoluutaadress (näiteks $A$1), suhteline aadress (nagu A1) või kombinatsioon nendest (A$1 või $A1). Saab määrata ka lehe nime.

Koostalitlusvõime huvides toetavad funktsioonid ADDRESS ja INDIRECT mittekohustuslikku parameetrit, mille abil saab määrata, kas tavapärase A1-kuju asemel tuleks kasutada aadressikuju R1V1.

Funktsioonis ADDRESS lisatakse see parameeter neljanda parameetrina, mis nihutab mittekohustusliku lehenime parameetri viiendale positsioonile.

Funktsioonis INDIRECT lisatakse parameeter teise parameetrina.

Kui argument sisestatakse väärtusega 0, kasutatakse mõlema funktsiooni korral kujul R1V1. Kui argumenti ei ole antud või selle väärtus pole 0, kasutatakse kuju A1.

R1V1-tähistuse korral tagastab ADDRESS aadressistringid kasutades lehenimede eraldajana hüüumärki '!' ning funktsioon INDIRECT eeldab lehenimede eraldajana hüüumärki. A1-tähistuse korral kasutavad mõlemad funktsioonid lehenimede eraldajana punkti '.'.

When opening documents from ODF 1.0/1.1 format, the ADDRESS functions that show a sheet name as the fourth parameter will shift that sheet name to become the fifth parameter. A new fourth parameter with the value 1 will be inserted.

Kui dokument salvestatakse ODF 1.0/1.1 vormingus ja ADDRESS-funktsioonidel on neljas parameeter, siis see parameeter eemaldatakse.

Ära salvesta arvutustabelit vanas ODF 1.0/1.1 vormingus, kui funktsiooni ADDRESS uus neljas parameeter on kasutatud väärtusega 0.

Funktsioon INDIRECT salvestatakse ilma ODF 1.0/1.1 vormingusse teisendamata. Kui teine parameeter oli olemas, tagastab Calci vanem versioon selle funktsiooni korral veaväärtuse.

### Syntax

ADDRESS(rida; veerg; abs; A1; "leht")

Rida on lahtriviite reanumber.

Veerg on lahtriviite veerunumber (number, mitte täht).

Abs määrab viite tüübi:

1: absoluutne ($A$1)

2: rida absoluutne, veerg suhteline (A$1)

3: rida suhteline; veerg absoluutne ($A1)

4: suhteline (A1)

A1 (mittekohustuslik) - kui see väärtus on 0, kasutatakse R1V1-tähistust. Kui see parameeter puudub või selle väärtus pole 0, kasutatakse A1-tähistust.

Leht on lehe nimi. See peab olema kahekordsetes jutumärkides.

### Näide:

=ADDRESS(1; 1; 2; "Leht2") tagastab: Leht2.A$1

If the formula above is in cell B2 of current sheet, and the cell A1 in sheet 2 contains the value -6, you can refer indirectly to the referenced cell using a function in B2 by entering =ABS(INDIRECT(B2)). The result is the absolute value of the cell reference specified in B2, which in this case is 6.

## AREAS

Tagastab mitmesesse alasse kuuluvate üksikute vahemike arvu. Vahemik võib koosneda kõrvutiasuvatest lahtritest või üksikust lahtrist.

Funktsioon eeldab üksikut argumenti. Kui esitada mitu vahemikku, tuleb need panna lisasulgudesse. Mitme vahemiku sisestamisel võib eraldajana kasutada semikoolonit (;), kuid see teisendatakse automaatselt tildeks (~). Tildet kasutatakse vahemike ühendamiseks.

### Syntax

AREAS(viide)

Viide tähistab viidet lahtrile või lahtrite vahemikule.

### Example

=AREAS((A1:B3;F2;G1)) tagastab 3, kuna see on viide kolmele lahtrile ja/või alale. Pärast sisestamist teisendatakse see kujule =AREAS((A1:B3~F2~G1)).

=AREAS(Kõik) tagastab väärtuse 1, kui oled aknas Andmed - Määra vahemik määranud ala nimega Kõik.

## CHOOSE

Tagastab indeksi abil väärtuse kuni 30 väärtuse loendist.

### Syntax

CHOOSE(indeks; väärtus1; ...; väärtus30)

Indeks on viide või arv vahemikus 1 kuni 30, mis näitab, milline väärtus tuleb loendist võtta.

Value1, Value2, ..., Value30 is the list of values entered as a reference to a cell or as individual values.

### Example

=CHOOSE(A1;B1;B2;B3;"Täna";"Eile";"Homme") näiteks tagastab lahtri B2 sisu, kui A1 = 2; kui A1 = 4, tagastab funktsioon teksti "Täna".

## COLUMN

Tagastab lahtriviite veerunumbri. Kui viidatud on lahtrile, tagastatakse selle lahtri veerunumber; kui parameeter on lahtrite ala, tagastatakse vastavad veerunumbrid üherealise massiivina, kui valem on sisestatud massiivivalemina. Kui alale viitava parameetriga funktsiooni COLUMN ei ole kasutatud massiivivalemi jaoks, määratakse ainult ala esimese lahtri veerunumber.

### Syntax

COLUMN(viide)

Viide on viide lahtrile või lahtrialale, mille esimese veeru numbrit otsitakse.

Kui viide puudub, tagastatakse veeru number, milles valem ise asub. LibreOffice Calc määrab viite aktiivsele lahtrile automaatselt.

### Example

=COLUMN(A1) võrdub 1. Veerg A on tabeli esimene veerg.

=COLUMN(C3:E3) võrdub 3. Veerg C on tabeli kolmas veerg.

=COLUMN(D3:G10) tagastab 4, kuna veerg D on tabelis neljas veerg ja funktsiooni COLUMN ei kasutata massiivivalemina. (Sel juhul kasutatakse tulemina alati massiivi esimest väärtust.)

{=COLUMN(B2:B7)} ja =COLUMN(B2:B7) tagastavad mõlemad 2, kuna viide sisaldab tabeli teise veeruna ainult veergu B. Kuna üheveerulistes alades on ainult üks veerunumber, pole vahet, kas valemit kasutatakse massiivivalemina või mitte.

=COLUMN() tagastab 3, kui valem sisestati veergu C.

{=COLUMN(Jänes)} tagastab üherealise massiivi (3, 4), kui "Jänes" on nimega ala (C1:D3).

## COLUMNS

Tagastab viitega määratud ala veergude arvu.

### Syntax

COLUMNS(massiiv)

Massiiv on viide lahtrivahemikule, mille veergude koguarvu soovitakse otsida. Argument võib olla ka üks lahter.

### Example

=COLUMNS(B5) tagastab 1, kuna lahter sisaldab ainult ühte veergu.

=COLUMNS(A1:C5) võrdub 3. Viide koosneb kolmest veerust.

=COLUMNS(Jänes) tagastab 2, kui Jänes on nimega vahemik (C1:D3).

## DDE

Tagastab DDE-põhise lingi tulemuse. Kui lingitud vahemiku või sektsiooni sisu muutub, siis muutub ka tagastatud väärtus. Värskendatud linkide kuvamiseks tuleb arvutustabel uuesti laadida või valida Redigeerimine - Lingid. Platvormidevahelised lingid, näiteks Windowsiga arvutis töötavast LibreOffice'i paigaldusest Linuxiga arvutis loodud dokumendile, pole lubatud.

### Syntax

DDE("server"; "fail"; "vahemik"; režiim)

Server is the name of a server application. LibreOffice applications have the server name "soffice".

Fail on faili täielik nimi koos selle aadressiga.

Vahemik on ala, mis sisaldab andmeid, mida käsitletakse.

Režiim on mittekohustuslik parameeter, mis juhib meetodit, mida DDE-server andmete arvudeks teisendamiseks kasutab.

Režiim | Efekt
0 või puudub | Lahtristiilile "Vaikimisi" vastav arvu vorming
1 | Andmeid käsitletakse alati vastavalt USA inglise keele standardvormingule
2 | Andmeid käsitletakse tekstina, neid arvudeks teisendamata

### Example

=DDE("soffice";"c:\office\document\data1.ods";"sheet1.A1") reads the contents of cell A1 in sheet1 of the LibreOffice Calc spreadsheet data1.ods.

=DDE("soffice";"c:\office\document\motto.odt";"Today's motto") returns a motto in the cell containing this formula. First, you must enter a line in the motto.odt document containing the motto text and define it as the first line of a section named Today's Motto (in LibreOffice Writer under Insert - Section). If the motto is modified (and saved) in the LibreOffice Writer document, the motto is updated in all LibreOffice Calc cells in which this DDE link is defined.

## ERRORTYPE

Tagastab arvu, mis vastab viidatud lahtris olevale vea koodile. Selle arvu abiga saab tekitada veateate teksti.

Vea korral tagastab funktsioon loogilise või arvulise väärtuse.

Kui klõpsata viga sisaldavale lahtrile, kuvatakse olekuribal LibreOffice-i eeldefineeritud veakoodi.

### Syntax

ERRORTYPE(viide)

Viide sisaldab selle lahtri aadressi, kus viga ilmneb.

### Example

Kui lahtris A1 kuvatakse viga Err:518, tagastab funktsioon =ERRORTYPE(A1) arvu 518.

## GETPIVOTDATA

Funktsioon GETPIVOTDATA tagastab tulemuseväärtuse liigendtabelist. Väärtuse aadressi jaoks kasutatakse välja- ja elemendinimesid, et see jääks kehtima ka liigendtabeli paigutuse muutumise korral.

### Syntax

Kasutada võib kaht erinevat süntaksit:

GETPIVOTDATA(sihtväli; liigendtabel; [ väli 1; element 1; ... ])

GETPIVOTDATA(liigendtabel; piirangud)

Teist süntaksit eeldatakse, kui antud on täpselt kaks argumenti, millest esimene on viide lahtrile või lahtrite vahemikule. Kõikidel muudel juhtumitel eeldatakse esimest süntaksit. Funktsiooninõustaja kuvab esimest süntaksit.

### Syntax

Sihtväli on string, mis valib ühe liigendtabeli andmeväljadest. String võib olla lähteveeru nimi või andmevälja nimi tabelis kuvatud kujul (nt "Summa - Müük").

Liigendtabel on viide lahtrile või lahtrivahemikule, mis asub liigendtabelis või sisaldab liigendtabelit. Kui lahtrivahemik sisaldab mitut liigendtabelit, kasutatakse viimati loodud tabelit.

Kui paarid väli n / element n on antud, tagastatakse kokkuvõte. Muul juhul lisab iga paar piirangu, mida tulemus peab täitma. Väli n on liigendtabeli välja nimi. Element n on sellelt väljalt pärineva elemendi nimi.

Kui liigendtabel sisaldab ainult ühte tulemuseväärtust, mis täidab kõik piirangud, või vahekokkuvõtet, mis summeerib kõik vastavad väärtused, tagastatakse tulemus. Kui vastavaid tulemusi pole või kui mitmel tulemusel pole vahekokkuvõtet, tagastatakse viga. Need tingimused kehtivad tulemustele, mis on liigendtabelisse kaasatud.

Kui lähteandmed sisaldavad kirjeid, mida liigendtabeli sätted peidavad, siis neid ignoreeritakse. Välja ja elemendi paaride järjestus pole oluline. Välja- ja elemendinimed pole tõstutundlikud.

Kui leheküljevälja jaoks pole piirangut määratud, kasutatakse vaikimisi välja valitud väärtust. Kui leheküljevälja jaoks on piirang määratud, peab see vastama välja valitud väärtusele, muidu tagastatakse viga. Leheküljeväljad on on liigendtabeli vasakpoolses ülaosas asuvad väljad, mis asustatakse liigendtabeli paigutuse dialoogi ala "Lehekülje väljad" kaudu. Igal leheküljeväljal saab valida elemendi (väärtuse), mis tähendab ainult selle elemendi kaasamist arvutusse.

Liigendtabeli vahekokkuvõtete väärtusi kasutatakse ainult juhul, kui need kasutatavad funktsiooni "automaatne" (v.a juhul, kui need on määratud piirangus; vt allpool lõiku Teine süntaks).

### Syntax

Liigendtabel on sama tähendusega nagu esimeses süntaksis.

Piirangud on tühikutega eraldatud loend. Kirjed võivad olla jutumärkides (ühekordsetes jutumärkides). Terve string peab olema jutumärkides (topeltjutumärkides), kui te just ei viita stringile mõnest teisest lahtrist.

Üks kirje võib olla andmevälja nimi. Andmevälja nime võib välja jätta, kui liigendtabel sisaldab ainult ühte andmevälja; muul juhul peab nimi olema määratud.

Iga muu kirje määrab piirangu kujul Väli[Element] (literaalimärkidega [ ja ]) või ainult kujul Element, kui elemendi nimi on kõigil liigendtabelis kasutatud väljadel unikaalne.

Funktsiooninime saab lisada kujul Väli[Element;Funktsioon]; sel juhul vastendatakse piirangut ainult seda funktsiooni kasutavate vahekokkuvõtete väärtustega. Võimalikud funktsiooninimed on Sum, Count, Average, Max, Min, Product, Count (ainult arvud), StDev (valim), StDevP (populatsioon), Var (valim) ja VarP (populatsioon); tõstutundetu.

## HLOOKUP

Otsib väärtust, viidates selle leidmisel valitud ala all olevale lahtrile. Funktsioon kontrollib, kas massiivi esimene rida sisaldab määratud väärtust. Seejärel tagastab funktsioon leitud lahtriga samas veerus oleva parameetriga indeks määratud rea lahtri sisu.

The search supports regular expressions. You can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must precede every character with a "\" character. You can switch the automatic evaluation of regular expression on and off in LibreOffice - Preferences Tools - Options
- LibreOffice Calc - Calculate.

### Syntax

HLOOKUP(SearchCriterion; Array; Index; Sorted)

See also: VLOOKUP (columns and rows are exchanged)

Tühjade lahtrite käsitlemine

## HYPERLINK

Kui klõpsata lahtrile, mis sisaldab funktsiooni HYPERLINK, avaneb hüperlink.

Mittekohustusliku parameetri lahtri tekst kasutamisel leiab valem URL-i ja kuvab seejärel teksti või arvu.

Hüperlingiga lahtri avamiseks klaviatuuri abil vali lahter, vajuta redigeerimisrežiimi sisenemiseks F2, vii kursor hüperlingi ette, vajuta Shift+F10 ja vali Ava hüperlink.

### Syntax

HYPERLINK("URL") või HYPERLINK("URL"; "lahtri tekst")

URL määrab lingi sihtkoha. Mittekohustuslik parameeter lahtri tekst on lahtris kuvatav tekst või arv, mis tagastatakse tulemusena. Kui parameetrit lahtri tekst pole määratud, kuvatakse lahtritekstina URL ja see tagastatakse ka tulemusena.

Tühjade lahtrite ja maatriksielementide korral tagastatakse arv 0.

### Example

=HYPERLINK("http://www.example.org") kuvab lahtris teksti "http://www.example.org" ja avab hüperlingi http://www.example.org, kui sellel klõpsata.

=HYPERLINK("http://www.example.org";"Klõpsa siin") kuvab lahtris teksti "Klõpsa siin" ja avab hüperlingi http://www.example.org, kui sellel klõpsata.

=HYPERLINK("http://www.example.org";12345) kuvab arvu 12345 ja avab hüperlingi http://www.example.org, kui sellel klõpsata.

=HYPERLINK($B4), kus lahter B4 sisaldab väärtust http://www.example.org. Funktsioon lisab hüperlingilahtri URL-ile http://www.example.org ja tagastab sama teksti, mida kasutatakse valemi tulemusena.

=HYPERLINK("http://www.";"Klõpsa ") & "example.org" kuvab lahtris teksti "Klõpsa example.org" ja avab hüperlingi http://www.example.org, kui sellel klõpsata.

=HYPERLINK("#Leht1.A1";"Mine algusse") kuvab teksti "Mine algusse" ja viib selles dokumendis lahtrisse Leht1.A1.

=HYPERLINK("file:///C:/writer.odt#Specification";"Go to Writer bookmark") displays the text "Go to Writer bookmark", loads the specified text document and jumps to bookmark "Specification".

## INDEX

INDEX tagastab alamvahemiku, mis on määratud rea ja veeru numbriga või mittekohustusliku vahemiku indeksiga. Sõltuvalt kontekstist tagastab INDEX kas viite või sisu.

### Syntax

INDEX(viide; rida; veerg; vahemik)

Viide on viide, mille saab sisestada kas otse või vahemiku nime määramisega. Kui viide koosneb mitmest vahemikust, tuleb viide või vahemikunimi panna sulgudesse.

Rida (mittekohustuslik) on selle viitevahemiku reaindeks, mille väärtus tagastada. Nulli korral (kindlat rida pole) tagastatakse kõik viidatud read.

Veerg (mittekohustuslik) on selle viitevahemiku veeruindeks, mille väärtus tagastada. Nulli korral (kindlat veergu pole) tagastatakse kõik viidatud veerud.

Vahemik (mittekohustuslik) on alamvahemiku indeks, kui viidatakse mitmikvahemikule.

### Example

=INDEX(Hinnad;4;1) tagastab väärtuse, mis asub aknas Andmed - Määra vahemik nimega Hinnad määratud andmebaasivahemikus reas 4 ja veerus 1.

=INDEX(SumX;4;1) returns the value from the range SumX in row 4 and column 1 as defined in Sheet - Named Ranges and Expressions - Define.

=INDEX(A1:B6;1) tagastab viite vahemiku A1:B6 esimesele reale.

=INDEX(A1:B6;0;1) tagastab viite vahemiku A1:B6 esimesele veerule.

=INDEX((multi);4;1) indicates the value contained in row 4 and column 1 of the (multiple) range, which you named under Sheet - Named Ranges and Expressions - Define as multi. The multiple range may consist of several rectangular ranges, each with a row 4 and column 1. If you now want to call the second block of this multiple range enter the number 2 as the range parameter.

=INDEX(A1:B6;1;1) osutab vahemiku A1:B6 vasakpoolses ülanurgas asuvale väärtusele.

=INDEX((mitu);0;0;2) tagastab viite mitmese ala teisele vahemikule.

## INDIRECT

Tagastab tekstistringiga määratud viite. Funktsioon võib tagastada ka stringiga määratud lahtrite vahemiku.

Koostalitlusvõime huvides toetavad funktsioonid ADDRESS ja INDIRECT mittekohustuslikku parameetrit, mille abil saab määrata, kas tavapärase A1-kuju asemel tuleks kasutada aadressikuju R1V1.

Funktsioonis ADDRESS lisatakse see parameeter neljanda parameetrina, mis nihutab mittekohustusliku lehenime parameetri viiendale positsioonile.

Funktsioonis INDIRECT lisatakse parameeter teise parameetrina.

Kui argument sisestatakse väärtusega 0, kasutatakse mõlema funktsiooni korral kujul R1V1. Kui argumenti ei ole antud või selle väärtus pole 0, kasutatakse kuju A1.

R1V1-tähistuse korral tagastab ADDRESS aadressistringid kasutades lehenimede eraldajana hüüumärki '!' ning funktsioon INDIRECT eeldab lehenimede eraldajana hüüumärki. A1-tähistuse korral kasutavad mõlemad funktsioonid lehenimede eraldajana punkti '.'.

When opening documents from ODF 1.0/1.1 format, the ADDRESS functions that show a sheet name as the fourth parameter will shift that sheet name to become the fifth parameter. A new fourth parameter with the value 1 will be inserted.

Kui dokument salvestatakse ODF 1.0/1.1 vormingus ja ADDRESS-funktsioonidel on neljas parameeter, siis see parameeter eemaldatakse.

Ära salvesta arvutustabelit vanas ODF 1.0/1.1 vormingus, kui funktsiooni ADDRESS uus neljas parameeter on kasutatud väärtusega 0.

Funktsioon INDIRECT salvestatakse ilma ODF 1.0/1.1 vormingusse teisendamata. Kui teine parameeter oli olemas, tagastab Calci vanem versioon selle funktsiooni korral veaväärtuse.

### Syntax

INDIRECT(viide; A1)

Viide on viide lahtrile või alale (teksti kujul), mille sisu tagastada.

A1 (mittekohustuslik) - kui see väärtus on 0, kasutatakse R1V1-tähistust. Kui see parameeter puudub või selle väärtus pole 0, kasutatakse A1-tähistust.

If you open an Excel spreadsheet that uses indirect addresses calculated from string functions, the sheet addresses will not be translated automatically. For example, the Excel address in INDIRECT("[filename]sheetname!"&B1) is not converted into the Calc address in INDIRECT("filename#sheetname."&B1).

### Example

=INDIRECT(A1) võrdub 100, kui lahter A1 sisaldab viidet C108 ja lahter C108 sisaldab väärtust 100.

=SUM(INDIRECT("a1:" & ADDRESS(1;3))) liidab ala A1 lahtrite väärtused kuni lahtrini, mille aadress on määratud reaga 1 ja veeruga 3. See tähendab, et liidetakse ala A1:C1 väärtused.

## LOOKUP

Returns the contents of a cell either from a one-row or one-column range. Optionally, the assigned value (of the same index) is returned in a different column and row. As opposed to VLOOKUP and HLOOKUP, search and result vector may be at different positions; they do not have to be adjacent. Additionally, the search vector for the LOOKUP must be sorted ascending, otherwise the search will not return any usable results.

Kui LOOKUP ei leia otsingukriteeriumi, leiab funktsioon vastavuse suurimale väärtusele otsinguvektoris, mis on väiksem sisestatud kriteeriumist või võrdne sellega.

The search supports regular expressions. You can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must precede every character with a "\" character. You can switch the automatic evaluation of regular expression on and off in LibreOffice - Preferences Tools - Options
- LibreOffice Calc - Calculate.

### Syntax

LOOKUP(otsingukriteerium; otsinguvektor; tulemusvektor)

Otsingukriteerium on otsitav väärtus, mis sisestatakse kas otse või viitena.

Otsinguvektor on üherealine või üheveeruline ala, kust otsida.

Tulemusvektor on teine üherealine või üheveeruline vahemik, kust funktsiooni tulemus võetakse. Tulemus on tulemusvektori lahter, millel on otsinguvektorist leitud eksemplariga sama indeks.

Tühjade lahtrite käsitlemine

### Example

=LOOKUP(A1;D1:D100;F1:F100) otsib vahemikust D1:D100 lahtrisse A1 sisestatud arvule vastavat lahtrit. Leitud üksuse korral määratakse kindlaks selle indeks, näiteks selle vahemiku 12. lahter. Seejärel tagastatakse 12. lahtri sisu selle funktsiooni väärtusena (tulemusvektoris).

## MATCH

Tagastab massiivi elemendi, mis vastab määratud väärtusele, suhtelise aadressi massiivis. Funktsioon tagastab otsingumassiivis leitud väärtuse asukoha arvuna.

### Syntax

MATCH(otsingukriteerium; otsingumassiiv; tüüp)

Otsingukriteerium on üherealisest või üheveerulisest massiivist otsitav väärtus.

Otsingumassiiv on otsitav viide. Otsingumassiiv võib olla üks rida või veerg või ühe rea või veeru osa.

Tüüp võib olla väärtus 1, 0 või -1. Kui tüüp = 1 või kui see mittekohustuslik parameeter puudub, siis eeldatakse, et otsingumassiivi esimene veerg on sorditud kasvavas järjestuses. Kui tüüp = -1, siis eeldatakse, et veerg on sorditud kahanevas järjestuses. See vastab samale funktsioonile Microsoft Excelis.

If Type = 0, only exact matches are found. If the search criterion is found more than once, the function returns the index of the first matching value. Only if Type = 0 can you search for regular expressions (if enabled in calculation options) or wildcards (if enabled in calculation options).

Kui tüüp = 1 või kolmas parameeter on puudu, tagastatakse otsingukriteeriumiga võrdse või sellest väiksema viimase väärtuse indeks. See kehtib ka juhul, kui otsingumassiiv pole sorditud. Kui tüüp = -1, tagastatakse esimene suurem või võrdne väärtus.

The search supports regular expressions. You can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must precede every character with a "\" character. You can switch the automatic evaluation of regular expression on and off in LibreOffice - Preferences Tools - Options
- LibreOffice Calc - Calculate.

### Example

=MATCH(200;D1:D100) otsib alast D1:D100, mis on sorditud veeru D aluse, väärtust 200. Kohe, kui jõutakse selle väärtuseni, tagastatakse selle rea number, kust väärtus leiti. Kui veerust otsimisel leitakse suurem väärtus, tagastatakse eelmise rea number.

## OFFSET

Tagastab viidatud lahtrist määratud arvu ridade ja veergude kaugusel oleva lahtri väärtuse.

### Syntax

OFFSET(viide; read; veerud; kõrgus; laius)

Viide on viide, kust funktsioon otsib uut viidet.

Read on nende ridade arv, mille võrra viidet on korrigeeritud ülespoole (negatiivne väärtus) või allapoole.

Read on nende ridade arv, mille võrra viidet on korrigeeritud ülespoole (negatiivne väärtus) või allapoole.

Kõrgus (mittekohustuslik) on uuest viiteasukohast algava ala vertikaalne kõrgus.

Laius (mittekohustuslik) on uuest viiteasukohast algava ala horisontaalne laius.

Argumendid read ja veerud ei tohi põhjustada algusrea või -veeru negatiivset ega nullväärtust.

Argumendid kõrgus ja laius ei tohi põhjustada ridade või veergude arvu negatiivset ega nullväärtust.

In the LibreOffice Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.

### Example

=OFFSET(A1;2;2) tagastab väärtuse lahtris C3 (A1 nihe kahe rea ja kahe veeru võrra allapoole). Kui C3 sisaldab väärtust 100, tagastab see funktsioon vastusena 100.

=OFFSET(B2:C3;1;1) tagastab viite vahemikule B2:C3, mis on nihutatud ühe rea võrra alla ja ühe veeru võrra paremale (C3:D4).

=OFFSET(B2:C3;-1;-1) tagastab viite vahemikule B2:C3, mis on nihutatud ühe rea võrra üles ja ühe veeru võrra vasakule (A1:B2).

=OFFSET(B2:C3;0;0;3;4) tagastab viite vahemikule B2:C3, mille suurust on muudetud nii, et see on nüüd 3 rida ja 4 veergu (B2:E4).

=OFFSET(B2:C3;1;0;3;4) tagastab viite vahemikule B2:C3, mis on nihutatud ühe rea võrra allapoole ja mille suurust on muudetud nii, et see on nüüd 3 rida ja 4 veergu (B2:E4).

=SUM(OFFSET(A1;2;2;5;6)) määrab selle ala summa, mis algab lahtrist C3 ning mille kõrgus on 5 rida ja laius 6 veergu (ala=C3:H7).

If the width or height is included, the OFFSET function returns a range and thus must be entered as an array formula. If both the width and height are missing, a cell reference is returned.

## ROW

Tagastab lahtriviitega määratud rea numbri. Kui viidatud on lahtrile, tagastatakse selle lahtri rea number. Kui viidatud on lahtrite vahemikule, tagastakse vastavad ridade numbrid üheveerulise massiivina, kui valem on sisestatud massiivi valemina. Kui funktsioon ROW viitega lahtrite vahemikule ei ole sisestatud massiivi valemina, tagastatakse ainult vahemiku esimese rea number.

### Syntax

ROW(viide)

Viide on lahter, ala või ala nimi.

Kui viide puudub, leitakse selle lahtri rea number, kuhu valem on sisestatud. LibreOffice Calc määrab viite aktiivsele lahtrile automaatselt.

### Example

=ROW(B3) tagastab 3, kuna viide viitab tabeli kolmandale reale.

{=ROW(D5:D8)} tagastab üheveerulise massiivi (5, 6, 7, 8), kuna määratud viide sisaldab ridu 5 kuni 8.

=ROW(D5:D8) tagastab 5, kuna funktsiooni ROW ei kasutata massiivivalemina ja tagastatakse ainult viite esimese rea number.

{=ROW(A1:E1)} ja =ROW(A1:E1) tagastavad mõlemad 1, kuna viide sisaldab tabeli esimese reana ainult rida 1. (Kuna üherealistes alades on ainult üks reanumber, pole vahet, kas valemit kasutatakse massiivivalemina või mitte.)

=ROW() tagastab 3, kui valem sisestati reas 3.

{=ROW(Jänes)} tagastab üheveerulise massiivi (1, 2, 3), kui "Jänes" on nimega ala (C1:D3).

## ROWS

Tagastab ridade arvu massiivis või vastavalt viitele.

### Syntax

ROWS(massiiv)

Massiiv on viide või nimega ala, mille ridade koguarvu soovitakse määrata.

### Example

=Rows(B5) tagastab 1, kuna lahter sisaldab ainult ühte rida.

=ROWS(A10:B12) tagastab 3.

=ROWS(Jänes) tagastab 3, kui "Jänes" on nimega ala (C1:D3).

## SHEET

Tagastab viite lehenumbri või lehe nime sisaldava stringi. Kui argumendid puuduvad, tagastatakse selle lehe number, mis sisaldab valemit.

### Syntax

SHEET(viide)

Viide pole kohustuslik ja viitab lahtrile, alale või lehenimestringile.

### Example

=SHEET(Leht2.A1) tagastab 2, kui Leht2 on tabelarvutusdokumendis teine leht.

## SHEETS

Tuvastab lehtede arvu viites. Kui argumendid puuduvad, tagastatakse aktiivse dokumendi lehtede arv.

### Syntax

SHEETS(viide)

Viide on viide lehele või alale. See parameeter pole kohustuslik.

### Example

=SHEETS(Leht1.A1:Leht3.G12) tagastab 3, kui Leht1, Leht2 ja Leht3 on olemas määratud järjestuses.

## STYLE

Applies a style to the cell containing the formula. After a set amount of time, another style can be applied. This function always returns the value 0, allowing you to add it to another function without changing the value. Together with the CURRENT function you can apply a color to a cell depending on the value. For example: =...+STYLE(IF(CURRENT()>3;"red";"green")) applies the style "red" to the cell if the value is greater than 3, otherwise the style "green" is applied. Both cell formats, "red" and "green" have to be defined beforehand.

### Syntax

STYLE("stiil"; aeg; "stiil2")

Stiil on lahtrile rakendatava lahtristiili nimi. Stiilinimed tuleb sisestada jutumärkides.

Aeg on mittekohustuslik ajavahemik sekundites. Kui see parameeter puudub, siis stiili ei muudeta pärast teatud aja möödumist.

Stiil2 on pärast teatud aja möödumist lahtrile rakendatava lahtristiili mittekohustuslik nimi. Kui see parameeter puudub, eeldatakse vaikestiili kasutamist.

In the LibreOffice Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.

### Example

=STYLE("Nähtamatu";60;"Vaikimisi") vormindab lahtri läbipaistva vorminguga 60 sekundiks pärast dokumendi uuestiarvutamist või laadimist; seejärel rakendatakse vorming Vaikimisi. Mõlemad lahtrivormingud peavad olema eelnevalt määratud.

Since STYLE() has a numeric return value of zero, this return value gets appended to a string. This can be avoided using T() as in the following example:

="Tekst"&T(STYLE("minustiil"))

Teine näide on funktsiooni CURRENT() juures.

## VLOOKUP

Vertical search with reference to adjacent cells to the right. This function checks if a specific value is contained in the first column of an array. The function then returns the value in the same row of the column named by Index. If the Sorted parameter is omitted or set to TRUE or one, it is assumed that the data is sorted in ascending order. In this case, if the exact SearchCriterion is not found, the last value that is smaller than the criterion will be returned. If Sorted is set to FALSE or zero, an exact match must be found, otherwise the error Error: Value Not Available will be the result. Thus with a value of zero the data does not need to be sorted in ascending order.

The search supports regular expressions. You can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must precede every character with a "\" character. You can switch the automatic evaluation of regular expression on and off in LibreOffice - Preferences Tools - Options
- LibreOffice Calc - Calculate.

### Syntax

=VLOOKUP(SearchCriterion; Array; Index; Sorted)

Otsingukriteerium on väärtus, mida otsitakse massiivi esimesest veerust.

Massiiv on viide, mis peab koosnema vähemalt kahest veerust.

Indeks on massiivi selle veeru number, mis sisaldab tagastatavat väärtust. Esimese veeru number on 1.

Sorted is an optional parameter that indicates whether the first column in the array is sorted in ascending order. Enter the Boolean value FALSE or zero if the first column is not sorted in ascending order. Sorted columns can be searched much faster and the function always returns a value, even if the search value was not matched exactly, if it is between the lowest and highest value of the sorted list. In unsorted lists, the search value must be matched exactly. Otherwise the function will return this message: Error: Value Not Available.

Tühjade lahtrite käsitlemine

### Example

You want to enter the number of a dish on the menu in cell A1, and the name of the dish is to appear as text in the neighboring cell (B1) immediately. The Number to Name assignment is contained in the D1:E100 array. D1 contains 100, E1 contains the name Vegetable Soup, and so forth, for 100 menu items. The numbers in column D are sorted in ascending order; thus, the optional Sorted parameter is not necessary.

Sisesta lahtrisse B1 järgmine valem:

=VLOOKUP(A1;D1:E100;2)

Niipea kui sisestad arvu lahtrisse A1, kuvab lahter B1 vastavat teksti, mis asub viidatud ala D1:E100 teises veerus. Kui sisestada arv, mida esimene veerg ei sisalda, tagastatakse lähimale väiksemale arvule vastav tekst. Kui sa ei soovi seda, sisesta neljanda parameetrina VÄÄR, siis tagastatakse esimesest veerust puuduva arvu sisestamisel veateade.

Sarnased teemad

Functions by Category