Module
Inhalte
Index 🔎︎

## Funktion MITTELWERTWENN

Ergibt das arithmetische Mittel aller Zellen eines Bereichs, die eine vorgegebene Bedingung erfüllen. Die Funktion MITTELWERTWENN addiert alle Werte, welche die Bedingung erfüllen, und teilt die Summe durch die Anzahl der zutreffenden Zellen.

### Syntax

MITTELWERTWENN(Bereich; Kriterium [; Mittelwertbereich ])

Bereich (erforderlich). Ein Zellbereich, der Name eines benannten Bereichs oder eine Zeilen-/Spaltenüberschrift, welche(r) die zu mittelnden Zahlen oder den Text für die Bedingung enthält.

Bedingung – erforderliches Argument. Eine Bedingung in Form eines Ausdrucks oder ein Zellbezug zu einem Ausdruck, der festlegt, welche Zellen zur Berechnung des Mittelwerts herangezogen werden sollen. Der Ausdruck kann Text, Zahlen, reguläre Ausdrücke (falls in den Optionen aktiviert) oder Platzhalter (falls in den Optionen aktiviert) enthalten.

Mittelwertbereich (optional). Ist ein Bereich mit Werten, für die der Mittelwert berechnet wird.

Beachten Sie, dass, wenn Mittelwertbereich nicht angegeben ist, Bereich für beides, die Berechnung des Mittelwerts und die Prüfung der Bedingung, verwendet wird. Wenn Mittelwertbereich angegeben ist, wird Bereich nur für die Prüfung der Bedingung und Mittelwertbereich nur für die Berechnung des Mittelwerts verwendet.
Kriterium muss eine Zeichenkette sein und als solche muss Kriterium in Anführungszeichen ("Kriterium") stehen, außer es ist ein Funktionsname, ein Zellbezug oder eine Zeichenverkettung (&).

Diese Funktion ist Teil des OpenDocument-Standards (Open Document Format for Office Applications) Version 1.2. (ISO/IEC 26300:2-2015)

Wenn einzelne Zellen des Bereichs für die Berechnung des Mittelwerts leer sind oder Text enthalten, ignoriert die Funktion MITTELWERTWENN diese Zellen.
Wenn der gesamte Bereich leer ist, nur Text enthält oder alle Werte des Bereichs nicht die Bedingung erfüllen (oder eine Kombinationen dieser), ergibt die Funktion den Fehlerwert #DIV/0!.

### Beispiel

#### Betrachten Sie folgende Tabelle

| A | B | C
1 | Produktname | Absatz | Einnahmen
2 | Buntstift | 20 | 65
3 | Stift | 35 | 85
4 | Schulbuch | 20 | 190
5 | Buch | 17 | 180
6 | Buntstift-Set | nicht | nicht

In allen unten stehenden Beispielen enthält der Bereich für die Berechnung der Summe die Zeile 6, diese wird aber ignoriert, da sie Text enthält.

In allen unten stehenden Berechnungen enthält der Bereich für die Berechnung des Mittelwertes die Zeile #6, diese wird aber ignoriert, da sie Text enthält.

#### Einfache Verwendung

=MITTELWERTWENN(B2:B6;"<35")

Berechnet den Mittelwert der Werte im Bereich B2:B6, die kleiner als 35 sind. Ergibt 19, da die zweite Zeile nicht in die Berechnung mit einbezogen wird.

=MITTELWERTWENN(B2:B6;"<"&MAX(B2:B6))

Berechnet den Mittelwert der Werte desselben Bereichs, die kleiner als der Maximalwert dieses Bereiches sind. Ergibt 19, da der größte Wert (in der zweiten Zeile) nicht in die Berechnung mit einbezogen wird.

=MITTELWERTWENN;">"&KKLEINSTE(B2:B6;1))

Berechnet den Mittelwert der Werte desselben Bereichs, die größer als der erst-kleinste Wert dieses Bereiches sind. Ergibt 25, da der erst-kleinste Wert (in der vierten Zeile) nicht in die Berechnung mit einbezogen wird.

#### Verwendung von Mittelwertbereich

=MITTELWERTWENN(B2:B6;"<35";C2:C6)

Die Funktion untersucht, welche Werte im Bereich B2:B6 kleiner als 35 sind, und berechnet den Mittelwert der entsprechenden Zellen im Bereich C2:C6. Ergibt 145, da die zweite Zeile nicht in die Berechnung mit einbezogen wird.

=MITTELWERTWENN(B2:B6;">"&MIN(B2:B6);C2:C6)

Die Funktion untersucht, welche Werte im Bereich B2:B6 größer als der größte Wert in B2:B6 sind, und berechnet den Mittelwert der entsprechenden Zellen im Bereich C2:C6. Ergibt 113,3, da die vierte Zeile (die den größten Wert im Bereich B2:B6 enthält) nicht in die Berechnung mit einbezogen wird.

=MITTELWERTWENN(B2:B6;"<"&KGRÖSSTE(B2:B6;2);C2:C6)

Die Funktion untersucht, welche Werte im Bereich B2:B6 kleiner als der zweit-kleinste Wert im Bereich B2:B6 sind, und berechnet den Mittelwert der entsprechenden Zellen im Bereich C2:C6. Ergibt 180, da nur die vierte Zeile in die Berechnung mit einbezogen wird.

#### Verwendung mit regulären Ausdrücken

=MITTELWERTWENN(A2:A6;"stift";B2:B6)

Die Funktion untersucht, welche Zellen im Bereich A2:A6 den Ausdruck „stift“ enthalten, und berechnet den Mittelwert der entsprechenden Zellen im Bereich B2:B6. Ergibt 35, da nur die zweite Zeile in die Berechnung mit einbezogen wird. Die Suche erfolgt in Bereich A2:A6, aber die Werte stammen aus dem Bereich B2:B6.

=MITTELWERTWENN(A2:A6;".*stift";B2:B6)

Die Funktion untersucht, welche Zellen im Bereich A2:A6 irgendwie beginnen und auf „stift“ enden, und berechnet den Mittelwert der entsprechenden Zellen im Bereich B2:B6. Ergibt 27,5, da zusätzlich „Bleistift“ die Bedingung erfüllt und somit die erste und die zweite Zeile in die Berechnung mit einbezogen werden.

=MITTELWERTWENN(A2:A6;".*buch.*";B2:B6)

Die Funktion untersucht, welche Zellen im Bereich A2:A6 „buch“ enthalten sowie irgendwie starten und enden, und berechnet den Mittelwert der entsprechenden Zellen im Bereich B2:B6. Ergibt 18,5, da nur die dritte und die vierte Zeile in die Berechnung mit einbezogen werden.

#### Bezüge zu einer Zelle mit einer Bedingung

Um die Bedingung einfach zu ändern, bietet es sich an, diese in einer separaten Zelle festzulegen und für die Bedingung der Funktion MITTELWERTWENN einen Bezug zur Zelle anzugeben.

=MITTELWERTWENN(A2:A6;".*"&E2&".*";B2:B6)

Die Funktion untersucht, welche Zellen im Bereich A2:A6 den Ausdruck aus Zelle E2 enthalten sowie irgendwie starten und enden, und berechnet den Mittelwert der entsprechenden Zellen im Bereich B2:B6. Wenn E2 = buch, ergibt die Funktion 18,5.

=MITTELWERTWENN(B2:B6;"<"&E2;C2:C6)

Die Funktion untersucht, welche Zellen im Bereich A2:A6 kleiner als der in Zelle E2 enthalte Wert sind, und berechnet den Mittelwert der entsprechenden Zellen im Bereich B2:B6. Wenn E2 = 35, ergibt die Funktion 145.

Verwandte Themen

MITTELWERT, MITTELWERTA, MITTELABW

ZÄHLENWENNS, MINWENNS, MAXWENNS, MITTELWERTWENNS, SUMMEWENNS

Liste der regulären Ausdrücke