Модул
Съдържание
Индекс 🔎︎

## Функция COUNTIFS

Връща броя на клетките, които отговарят на критериите, в няколко диапазона.

### Синтаксис

COUNTIFS(Диапазон1; Критерий1 [; Диапазон2; Критерий2 [; ...]])

Диапазон1 – задължителен аргумент. Диапазон от клетки, име на наименуван диапазон или заглавие на ред или колона за преброяване и проверка на съответния критерий.

Критерий1 – задължителен аргумент. Низов израз, представляващ логическо условие или обръщение към клетка с такова. Условието може да съдържа текст, числа, регулярни изрази или заместващи знаци (ако са разрешени в настройките за изчисляване).

Диапазон2 – незадължителен. „Диапазон2“ и всички следващи имат значение, аналогично на „Диапазон1“.

Критерий2 – незадължителен. „Критерий2“ и всички следващи имат значение, аналогично на „Критерий1“.

Диапазон1, Диапазон2... и Критерий1, Критерий2, ... трябва да имат еднакъв размер, иначе функцията ще върне err:502 - невалиден аргумент.

Логическата връзка между критериите може да се дефинира като логическо И (конюнкция). С други думи, стойността на съответната клетка от Функ_диапазон се включва в изчислението тогава и само тогава, когато са изпълнени всички зададени критерии.

Функцията може да има до 255 аргумента, което означава, че можете да зададете 127 диапазона и критерии за тях.

Стойност TRUE в клетка се третира като 1, а FALSE – като 0 (нула).

Тази функция е от стандарта Open Document Format for Office Applications (OpenDocument) версия 1.2. (ISO/IEC 26300:2-2015)

### Пример

#### Да разгледаме следната таблица:

| A | B | C
1 | Име на продукт | Продажби | Приходи
2 | лепенки | 20 | 65
3 | лепило | 35 | 85
4 | пастели | 20 | 190
5 | пълнители | 17 | 180
6 | бележници | не | не

Във всички примери по-долу диапазонът за изчисляване съдържа ред №6, който се игнорира, защото съдържа текст.

#### Проста употреба

=COUNTIFS(B2:B6;">=20")

Преброява редовете от диапазона B2:B6 със стойности, по-големи или равни на 20. Връща 3, защото петият и шестият ред не отговарят на критерия.

=COUNTIFS(B2:B6;">=20";C2:C6;">70")

Преброява редовете, които съдържат едновременно стойности, по-големи от 70 в диапазона C2:C6 и стойности, по-големи или равни на 20 в диапазона B2:B6. Връща 2, защото вторият, петият и шестият ред не удовлетворяват всички критерии.

#### Използване на регулярни изрази и вложени функции

=COUNTIFS(B2:B6;"[:alpha:]*")

Преброява редовете от диапазона B2:B6, които съдържат само букви. Връща 1, защото само шестият ред изпълнява критерия.

=COUNTIFS(B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Преброява редовете от диапазона B2:B6 с изключение на тези с минималната и максималната стойност в диапазона. Връща 2, защото третият, петият и шестият ред не удовлетворяват всички критерии.

=COUNTIFS(A2:A6;"леп.*";B2:B6;"<"&MAX(B2:B6))

Преброява редовете, съответстващи на всички стойности от диапазона A2:A6, които започват с „леп“ и на всички стойности от диапазона B2:B6 освен максималната. Връща 1, защото само вторият ред удовлетворява всички критерии.

#### Обръщение към клетка като критерий

Ако е необходимо лесно да промените някой критерий, може да го зададете в отделна клетка и в условието на функцията COUNTIFS да използвате обръщение към тази клетка. Например горната функция може да бъде пренаписана както следва:

=COUNTIFS(A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

Ако E2 = "леп", функцията връща 1, защото връзката към клетката се замества със съдържанието ѝ и функцията работи като в предишния пример.

Теми, свързани с показаната

COUNT, COUNTIF, COUNTBLANK, COUNTA

COUNTIFS, MINIFS, MAXIFS, AVERAGEIFS, SUMIFS

Списък на регулярните изрази